***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Mar. 13, 2020                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt   PJS6603_Pch-part   D   G   S
*****param & model definition***
.model  dmos  pmos(
+    l = 1e-6		  w = 1e-6		level = 3
+  vto = -1.35		 kp = 4.724		   rb = 1.545e-2)
.model  dds   d(
+   is = 8.644e-13	  n = 1.142e0		   rs = 5.826e-2		ikf = 5.842e-2
+   eg = 1.201e0       trs1 = -1.092e-3 	 tikf = 3.721e-3)
.model  dbody d(
+   is = 9.644e-13	  n = 1.142e0		   rs = 5.826e-2		ikf = 5.842e-2
+   eg = 1.201e0       trs1 = -1.092e-3 	 tikf = 3.721e-3
+  cjo = 4.910e-11	  m = 3.229e-1		   vj = 1.299e-1
+   bv = 33		ibv = 250e-6		 tbv1 = 8.346e-4		 tt = 25n)
.model  inter  pmos(
+  vto = 0		 kp = 10		level = 1)
.model  dgd   d(
+  cjo = 2.410e-10	  m = 5.263e-1		   vj = 3.804e-1)
.param
+  cgs = 6.053e-10	cgd = 2.397e-10
+   rd = 2.767e-2	 ra = 2.413e-2		 trd1 = 8.349e-3
*****function & circuit***
rg	 G   1t   1
cgs	 1t   3   {cgs}
egv	 3   2t   table   {v(S, 1t)}
+((0.00 , 0.00 ),
+ (1.00 , 1.00 ),
+ (2.00 , 2.00 ),
+ (2.25 , 2.25 ),
+ (2.50 , 2.50 ),
+ (2.75 , 2.75 ),
+ (3.00 , 3.00 ),
+ (4.00 , 4.00 ),
+ (4.50 , 4.50 ),
+ (6.00 , 5.50 ),
+ (8.00 , 6.25 ),
+ (10.0 , 6.75 ),
+ (12.0 , 6.80 ),
+ (14.0 , 6.80 ))
egt	  1  2t   value = {6.021e-4*limit(v(2t,3),-5,0)*limit((temp-25),-80,125)}
mmain	  2   1   3   3   dmos
rd	  D   4   {rd}    tc = {trd1}
dds	  4   3   dds
dbody	  D   3   dbody
ra	  4   2   {ra}
rs	  3   5   1e-4
ls	  5   S   0.001n
m1       1t   8   6   6   inter
e1        8   6   4  1t   2
cgd	  7   4   {cgd}
rcgd      7   4   10meg
dgd       4   6   dgd
rdgd      4   6   10meg
m2        7   9  1t  1t   inter
e2        9  1t   4  1t   -2
.ends
*$
.subckt   PJS6603_Nch-part   D   G   S
*****param & model definition***
.model  dmos  nmos(
+    l = 1e-6		  w = 1e-6		level = 3
+  vto = 1.50		 kp = 5.67		   rb = 4e-2)
.model  dds   d(
+   is = 1.811e-13	  n = 1.028		   rs = 2.402e-2		 ikf = 3.513e-1
+   eg = 1.082	       trs1 = 3.578e-3 )
.model  dbody d(
+   is = 1.811e-13	  n = 1.028		   rs = 2.402e-2		 ikf = 3.513e-1
+   eg = 1.082	       trs1 = 3.578e-3 )
+  cjo = 4.045e-11	  m = 2.911e-1		   vj = 2.266e-2
+   bv = 33		ibv = 250e-6		 tbv1 = 1.885e-3		tbv2 = -6.655e-6
+   tt = 25n)
.model  inter  nmos(
+  vto = 0		 kp = 10		level = 1)
.model  dgd   d(
+  cjo = 1.328e-10	  m = 5.684e-1		   vj = 6.633e-1)
.param
+  cgs = 3.504e-10	cgd = 1.272e-10
+   rd = 4.064e-4	 ra = 3.027e-4		 trd1 = 1.025e-2
*****function & circuit***
rg	  G  1t   1
cgs	 1t   3   {cgs}
egv	 2t   3   table   {v(1t, S)}
+((0.00 , 0.00 ),
+ (0.50 , 0.50 ),
+ (1.00 , 1.00 ),
+ (2.00 , 2.00 ),
+ (2.50 , 2.50 ),
+ (3.00 , 3.00 ),
+ (4.00 , 4.25 ),
+ (5.00 , 5.30 ),
+ (6.00 , 6.00 ),
+ (8.00 , 6.70 ),
+ (10.0 , 7.00 ),
+ (12.0 , 7.20 ))
egt	  1  2t   value = {5.987e-4*limit(v(2t,3),0,5)*limit((temp-25),-80,125)}
mmain	  2   1   3   3   dmos
rd	  D   4   {rd}    tc = {trd1}
dds	  3   4   dds
dbody	  3   D   dbody
ra	  4   2   {ra}
rs	  3   5   1e-4
ls	  5   S   0.001n
m1    	 1t   8   6   6   inter
e1       8   6   4  1t   2
cgd	  7   4   {cgd}
rcgd      7   4   10meg
dgd       6   4   dgd
rdgd      4   6   10meg
m2        7   9  1t  1t   inter
e2        9  1t   4  1t   -2
.ends
*$
